#!/bin/tcsh -f

set version = 1.0.1alpha

set rootdir = `pwd`

cat << DESC_END
-----------------------------------------------
 Goose software package back up program
-----------------------------------------------
DESC_END

./script/clean
find . -name goosetmp -exec rm -rf {} \;
find . -name a.out -exec rm -rf {} \;
rm ./init/pl*
foreach f (./sample/*)
  if (-d $f) then
    echo cleaning up $f ...
    cd $f
    make clean
    cd ${rootdir}
    echo done.
    echo ''
  endif
end

set rootnamedefault = goosepkg${version}

LABEL_ROOTNAME:
set rootname = ${rootnamedefault}
echo ""
echo -n "Specify the root name for the package (default ${rootname}): "
set answer = $<
if (${answer} != '') then
  set rootname = ${answer}
endif
if (-f ${rootname}.tar.gz) then
  echo -n "${rootname}.tar.gz exists. Overwrite? (y/n): "
  set answer = $<
  if (${answer} != 'y') then
    goto LABEL_ROOTNAME
  endif
endif
rm -rf ${rootname}.tar.gz

mkdir tmp$$
mkdir tmp$$/${rootname}

tar cvfz tmp$$.tar.gz \
    ./00*\
    ./doc/{Makefile*,*.{txt,pdf,tex,obj,jpg,gif,sty,template},genreadme}\
    ./singutil ./bin ./lib ./include ./script/\
    ./sample ./init ./misc

cd tmp$$/${rootname}
tar xvfz ../../tmp$$.tar.gz
cd ..
tar cvfz ./${rootname}.tar.gz ./${rootname}
mv ./${rootname}.tar.gz ..
cd ..
/bin/rm -rf tmp$$ tmp$$.tar.gz
echo "Created ./${rootname}.tar.gz"
echo ""
